plugins {
    id "com.jfrog.bintray" version "1.1"
    id "com.github.jruby-gradle.base" version "0.1.5"
    id "java"
    id "idea"
}

compileJava {
    options.compilerArgs = ['-Xlint:all']
}

import com.github.jrubygradle.JRubyExec
repositories {
    mavenCentral()
    jcenter()
}
configurations {
    provided
}

version = "0.2.0"

dependencies {
    compile  "org.embulk:embulk-core:0.8.15"
    compile  "com.hierynomus:sshj:0.19.1"
    compile  "com.jcraft:jzlib:1.1.3"
    provided "org.embulk:embulk-core:0.8.15"
    testCompile "org.embulk:embulk-standards:0.8.15"
    testCompile "org.embulk:embulk-test:0.8.15"
    testCompile "com.github.docker-java:docker-java:3.0.7"
// for local testing
//    testCompile files('../embulk/embulk-test/build/libs/embulk-test-0.8.15.jar')
//    testCompile 'junit:junit:4.12'
//    testCompile 'org.hamcrest:hamcrest-library:1.3'
}

task classpath(type: Copy, dependsOn: ["jar"]) {
    doFirst { file("classpath").deleteDir() }
    from (configurations.runtime - configurations.provided + files(jar.archivePath))
    into "classpath"
}
clean { delete 'classpath' }

task gem(type: JRubyExec, dependsOn: ["build", "gemspec", "classpath"]) {
    jrubyArgs "-rrubygems/gem_runner", "-eGem::GemRunner.new.run(ARGV)", "build"
    script "build/gemspec"
    doLast { ant.move(file: "${project.name}-${project.version}.gem", todir: "pkg") }
}

task gemspec << { file("build/gemspec").write($/
Gem::Specification.new do |spec|
  spec.name          = "${project.name}"
  spec.version       = "${project.version}"
  spec.authors       = ["Shinichi Ishimura"]
  spec.summary       = %[Remote file input plugin for Embulk]
  spec.description   = %[Reads files stored on Remote hosts by SCP.]
  spec.email         = ["shiketaudonko41@gmail.com"]
  spec.licenses      = ["MIT"]
  spec.homepage      = "https://github.com/kamatama41/embulk-input-remote"

  spec.files         = `git ls-files`.split("\n") + Dir["classpath/*.jar"]
  spec.test_files    = spec.files.grep(%r"^(test|spec)/")
  spec.require_paths = ["lib"]

  spec.add_development_dependency 'bundler', ['~> 1.0']
  spec.add_development_dependency 'rake', ['>= 10.0']
end
/$)
}