Contents

namespace "SensuDashboard.Views", (exports) ->

  class exports.List extends SensuDashboard.Views.Base

    collectionEl: "tbody"

    itemName: "list_item"

    itemClass: ->
      exports.ListItem

    itemView: (model) ->
      kls = @itemClass()
      view = new kls(model: model, name: @itemName)

    initialize: ->
      @listenTo(@collection, "remove", @renderEmpty)
      @listenTo(@collection, "reset", @render)
      @listenTo(@collection, "add", @render)

    addItem: (item) ->
      @renderItem(item)
      @collection.sort()

    renderItem: (item) ->
      item_view = @itemView(item)
      @$el.find(@collectionEl).append(item_view.render().el)

    renderCollection: (collection = @collection) ->
      unless @renderEmpty(collection)
        collection.each (item) =>
          @renderItem(item)

    renderEmpty: (collection = @collection) ->
      if collection.isEmpty()
        tmpl = HandlebarsTemplates["empty_list"]
        @$el.html(tmpl())
        true
      else
        false

    render: ->
      @$el.html(@template())
      @renderCollection()

Version data entries

2 entries across 2 versions & 1 rubygems

Version	Path
sensu-dashboard-0.10.0	lib/sensu-dashboard/assets/javascripts/views/list.coffee
sensu-dashboard-0.9.9	lib/sensu-dashboard/assets/javascripts/views/list.coffee