Contents

class Lanes.Screens.Commands extends Lanes.Models.State

    constructor: (@screen, @options = {}) ->
        _.defaults(@options, modelName: 'model')
        _.bindAll(this, _.functionsIn(this))

    resetModel: ->
        model = @getModel()
        @setModel( new model.constructor )
        undefined

    getModel: -> @screen[@options.modelName]

    setModel: (model) ->
        @options.modelWillRebind?(model)
        @screen.data.rebind("#{@options.modelName}": model)
        @screen.setModelUrl?(model)
        @options.modelDidRebind?(model)

    canEditModel: ->
        @screen.hasWriteAccess?()

    getSyncOptions: ->
        _.result(@screen, 'syncOptions') || {}

    saveModel: ->
        @getModel().save(@getSyncOptions())

    toggleEdit: ->
        @screen.setState(isEditing: !@isEditing())

    isEditing: ->
        !!@screen.state.isEditing

Version data entries

3 entries across 3 versions & 1 rubygems

Version	Path
lanes-0.5.6	client/lanes/screens/Commands.coffee
lanes-0.5.5	client/lanes/screens/Commands.coffee
lanes-0.5.0	client/lanes/screens/Commands.coffee