plugins {
    id "java"
    id "com.github.kamatama41.embulk" version "0.5.2"
    id "net.researchgate.release" version "2.8.0"
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    maven { url 'http://kamatama41.github.com/maven-repository/repository' }
}

configurations {
    serverRuntime
    serverRuntime.extendsFrom runtime, testRuntime

    [compileClasspath, testCompileClasspath].each {
        it.resolutionStrategy.activateDependencyLocking()
    }
}

dependencies {
    compile("com.github.kamatama41:nsocket:0.3.4") {
        // Use embulk-core's Jackson (2.6.7) instead
        exclude group: "com.fasterxml.jackson.core", module: "jackson-databind"
    }
    // Followings are needed for running EmbulkServer
    implementation "org.embulk:embulk-standards:0.9.17"
    serverRuntime "org.embulk:embulk-standards:0.9.17"
    implementation "ch.qos.logback:logback-classic:1.2.3"
    serverRuntime "ch.qos.logback:logback-classic:1.2.3"
    implementation "ch.qos.logback:logback-core:1.2.3"
    serverRuntime "ch.qos.logback:logback-core:1.2.3"

    testImplementation "org.embulk:embulk-standards:0.9.17"
    testImplementation "org.embulk:embulk-test:0.9.17"
    testImplementation "com.github.kamatama41:embulk-test-helpers:0.8.0"
    testImplementation "org.junit.jupiter:junit-jupiter-api:5.3.2"
    testRuntime "org.junit.jupiter:junit-jupiter-engine:5.3.2"
}

task executableEmbulkServer(type: Jar) {
    manifest {
        attributes 'Main-Class': "org.embulk.executor.remoteserver.Launcher"
    }
    baseName = 'embulk-server'
    from { (sourceSets.main.output + configurations.serverRuntime).collect { it.isDirectory() ? it : zipTree(it) } }
    with jar
}

embulk {
    version = "0.9.17"
    category = "executor"
    name = "docker"
    authors = ["Shinichi Ishimura"]
    email = "shiketaudonko41@gmail.com"
    description = "Embulk executor plugin to run plugins on remote server."
    licenses = ["MIT"]
    homepage = "https://github.com/kamatama41/embulk-executor-remoteserver"
}

test {
    useJUnitPlatform()
}

release {
    git { requireBranch = 'master' }
}
afterReleaseBuild.dependsOn gemPush