/*
 * xtc - The eXTensible Compiler
 * Copyright (C) 2005 Robert Grimm
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
 */

/**
 * Definition of Java identifiers.
 *
 * @author Robert Grimm
 * @version $Revision: 1.4 $
 */
module xtc.lang.JavaIdentifier(Symbol, Spacing);

import Symbol;
import Spacing;

body {
  static {
    reserve(new String[] {
      "abstract", "default", "if",         "private",     "this",
      "boolean",  "do",      "implements", "protected",   "throw",
      "break",    "double",  "import",     "public",      "throws",
      "byte",     "else",    "instanceof", "return",      "transient",
      "case",     "extends", "int",        "short",       "try",
      "catch",    "final",   "interface",  "static",      "void",
      "char",     "finally", "long",       "strictfp",    "volatile",
      "class",    "float",   "native",     "super",       "while",
      "const",    "for",     "new",        "switch",
      "continue", "goto",    "package",    "synchronized"
    });
  }
}

option reserved;

generic QualifiedIdentifier =
  Identifier ( void:".":Symbol Identifier )*
  ;

String Identifier =
  yyValue:Word &{ ! RESERVED.contains(yyValue) } ;

String Word = WordCharacters Spacing ;

transient String WordCharacters =
  start:_ &{ Character.isJavaIdentifierStart(start) }
    ( part:_ &{ Character.isJavaIdentifierPart(part) } )*
  ;