Contents

# Maintainer: Max Meyer <[e-mail]>
pkgname=local_pac
pkgver=0.1.6
pkgrel=2
pkgdesc="local pacfile serving server"
arch=(i686 x86_64)
url="https://github.com/dg-vrnetze/${pkgname}"
license=('MIT')
depends=(ruby)
makedepends=(rubygems filegen)
source=(http://gems.rubyforge.org/gems/$pkgname-$pkgver.gem)
noextract=($pkgname-$pkgver.gem)
sha256sums=('1141ef7b1eafd1b67fe210ae3dde9d72b397b48842ae6b3f377a093af56a9094')

package() {
  cd "$srcdir"

  _library_dir=/usr/lib/${pkgname}
  _share_dir="${_library_dir}/gems/${pkgname}-${pkgver}/share"
  _systemd_dir=/usr/lib/systemd/system
  _bin_dir=/usr/bin

  install -d ${pkgdir}/$_library_dir 
  install -d ${pkgdir}/$_bin_dir 
  install -d ${pkgdir}/$_systemd_dir 

  GEM_HOME="${pkgdir}/${_library_dir}" GEM_ROOT="${pkgdir}/${_library_dir}" GEM_PATH="${pkgdir}/${_library_dir}" gem install --env-shebang --wrappers --no-ri --no-rdoc --install-dir ${pkgdir}/${_library_dir} $pkgname

  SOFTWARE_BINARY=$_library_dir/gems/${pkgname}-${pkgver}/bin/${pkgname} SOFTWARE_LIB=/usr/lib/local_pac filegen  ${pkgdir}${_share_dir}/archlinux/startup.erb > ${pkgdir}${_bin_dir}/${pkgname}

  chmod a+x ${pkgdir}/${_bin_dir}/${pkgname}
  rm -rf ${pkgdir}/${_library_dir}/cache
  rm -rf ${pkgdir}/${_library_dir}/{build_info,doc}

  install -D -m644 ${pkgdir}/$_share_dir/systemd/${pkgname}.service ${pkgdir}/$_systemd_dir
  install -D -m644 ${pkgdir}/$_share_dir/systemd/${pkgname}@.service ${pkgdir}/$_systemd_dir
  #install -D -m644 ${pkgdir}/$_share_dir/systemd/${pkgname}.socket ${pkgdir}/$_systemd_dir

  install -D -m644 ${pkgdir}${_share_dir}/../LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

# vim:set ts=2 sw=2 et:

Version data entries

1 entries across 1 versions & 1 rubygems

Version	Path
local_pac-0.1.7	share/archlinux/PKGBUILD