Sha256: 70354e25ceb26fe934f8cc327cc17853b54280c3bc5e36d331cf4666c317d75e

Contents?: true

Size: 1.96 KB

Versions: 11

Compression:

Stored size: 1.96 KB

Contents

class apache::mod::peruser (
  $minspareprocessors = '2',
  $minprocessors = '2',
  $maxprocessors = '10',
  $maxclients = '150',
  $maxrequestsperchild = '1000',
  $idletimeout = '120',
  $expiretimeout = '120',
  $keepalive = 'Off',
) {
  if defined(Class['apache::mod::event']) {
    fail('May not include both apache::mod::peruser and apache::mod::event on the same node')
  }
  if defined(Class['apache::mod::itk']) {
    fail('May not include both apache::mod::peruser and apache::mod::itk on the same node')
  }
  if defined(Class['apache::mod::prefork']) {
    fail('May not include both apache::mod::peruser and apache::mod::prefork on the same node')
  }
  if defined(Class['apache::mod::worker']) {
    fail('May not include both apache::mod::peruser and apache::mod::worker on the same node')
  }
  File {
    owner => 'root',
    group => $apache::params::root_group,
    mode  => '0644',
  }

  $mod_dir = $apache::mod_dir

  # Template uses:
  # - $minspareprocessors
  # - $minprocessors
  # - $maxprocessors
  # - $maxclients
  # - $maxrequestsperchild
  # - $idletimeout
  # - $expiretimeout
  # - $keepalive
  # - $mod_dir
  file { "${apache::mod_dir}/peruser.conf":
    ensure  => file,
    content => template('apache/mod/peruser.conf.erb'),
    require => Exec["mkdir ${apache::mod_dir}"],
    before  => File[$apache::mod_dir],
    notify  => Service['httpd'],
  }
  file { "${apache::mod_dir}/peruser":
    ensure  => directory,
    require => File[$apache::mod_dir],
  }
  file { "${apache::mod_dir}/peruser/multiplexers":
    ensure  => directory,
    require => File["${apache::mod_dir}/peruser"],
  }
  file { "${apache::mod_dir}/peruser/processors":
    ensure  => directory,
    require => File["${apache::mod_dir}/peruser"],
  }

  apache::peruser::multiplexer { '01-default': }

  case $::osfamily {
    'freebsd' : {
      class { 'apache::package':
        mpm_module => 'peruser'
      }
    }
    default: {
      fail("Unsupported osfamily ${::osfamily}")
    }
  }
}

Version data entries

11 entries across 11 versions & 1 rubygems

Version Path
freighthop-0.6.1 modules/apache/manifests/mod/peruser.pp
freighthop-0.6.0 modules/apache/manifests/mod/peruser.pp
freighthop-0.5.2 modules/apache/manifests/mod/peruser.pp
freighthop-0.5.1 modules/apache/manifests/mod/peruser.pp
freighthop-0.5.0 modules/apache/manifests/mod/peruser.pp
freighthop-0.4.1 modules/apache/manifests/mod/peruser.pp
freighthop-0.4.0 modules/apache/manifests/mod/peruser.pp
freighthop-0.3.3 modules/apache/manifests/mod/peruser.pp
freighthop-0.3.2 modules/apache/manifests/mod/peruser.pp
freighthop-0.3.1 modules/apache/manifests/mod/peruser.pp
freighthop-0.3.0 modules/apache/manifests/mod/peruser.pp