Contents

Rev.registerComponent 'Input',

  getDefaultProps: ->
    dom: "input"

  getTypeClassMod: ->
    if @props.dom == 'input'
      @props.type or 'text'
    else
      @props.dom

  render: ->
    labelClasses =
      'RevInput': true
      'RevInput--label': true
      'error': @props.error
    labelClasses["RevInput-#{@getTypeClassMod()}"] = true # RevInput-checkbox etc.
    labelClassName = @cx labelClasses

    <label className={labelClassName}>
      {@renderLabel() unless @shouldPutLabelAfterInput()}
      {@renderInput()}
      {@renderLabel() if @shouldPutLabelAfterInput()}
      {@renderError()}
    </label>

  renderInput: ->
    inputProps = _(@getPropsWithout 'dom', 'error', 'className').extend
      className: @classAdd
        'RevInput--input': true
        'error': @props.error

    React.createElement @props.dom, inputProps, @props.children

  shouldPutLabelAfterInput: ->
    @props.type == 'checkbox' or @props.type == 'radio'

  renderLabel: ->
    <span className="RevInput--innerLabel">{@props.label}</span>

  renderError: ->
    <small className="RevError error">{@props.error}</small> if @props.error

Version data entries

2 entries across 2 versions & 1 rubygems

Version	Path
revelry_core-0.1.11.6	app/assets/javascripts/revelry/ui/forms/Input.js.cjsx
revelry_core-0.1.11.5	app/assets/javascripts/revelry/ui/forms/Input.js.cjsx