Contents

subprojects {
  afterEvaluate { Project project ->

    configurations {
      starterSourceCompile.extendsFrom compile
      starterSourceRuntime.extendsFrom runtime

      exerciseTestsCompile.extendsFrom testCompile
      exerciseTestsRuntime.extendsFrom testRuntime
    }

    sourceSets {
      // Verify that the tests are working by running them against the reference solution.
      // By replacing the "main" sourceSet with the reference solution we avoid any collisions
      // with solution code that may have been included as a "starter" (e.g. etl).
      main {
        kotlin.srcDirs = [".meta/src/reference/kotlin"]
      }
      project["compileKotlin"].doFirst { compileTask ->
        println "  (source = " + compileTask.source.asPath + ")"
      }

      starterSource {
        kotlin.srcDirs = ["src/main/kotlin"]
      }
      project["compileStarterSourceKotlin"].doFirst { compileTask ->
        println "  (source = " + compileTask.source.asPath + ")"
      }

      exerciseTests {
        kotlin {
          srcDirs = ["src/test/kotlin"]
          compileClasspath += main.output
          runtimeClasspath += main.output
        }
      }

      // In lieu of being able to disable @Ignore in JUnit tests, we filter
      // those annotations, placing the edited tests in the path named here.
      test {
        kotlin.srcDirs = ["build/gen/test/kotlin"]
      }
      project["compileTestKotlin"].doFirst { compileTask ->
        println "  (test source = " + compileTask.source.asPath + ")"
      }
    }

    // Note that journey-test.sh also strips @Ignore annotations using sed. The
    // stripping implementations here and in journey-test.sh should be kept
    // consistent.
    task copyTestsFilteringIgnores(type: Copy) {
      from "src/test/kotlin"
      into "build/gen/test/kotlin"
      filter { line -> line.contains("@Ignore") ? "" : line }
    }

    test.dependsOn(copyTestsFilteringIgnores)
  }
}

Version data entries

150 entries across 150 versions & 1 rubygems

Version	Path
trackler-2.2.1.139	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.138	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.137	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.136	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.135	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.134	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.133	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.132	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.131	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.130	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.129	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.128	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.127	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.126	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.125	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.124	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.123	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.122	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.121	tracks/kotlin/exercises/build.gradle
trackler-2.2.1.120	tracks/kotlin/exercises/build.gradle